gaugeTransform -- computes the gauge transform of a system of connection matrices

Usage:

gaugeTransform(M, A, D)

gaugeTransform(M, A)
Inputs:
- M, a matrix, change of basis matrix
- A, a list, a system of connection matrices
- D, a ring, the Weyl algebra (if omitted, it will be inferred from first element of A)
Outputs:
- L, a list, the system of connection matrices $\widetilde{A}_i = M A_i M^{-1} + (\partial_i \bullet M)M^{-1}$ after the gauge transformation with respect to $M$.

Description

This method computes the gauge transform of a system of connection matrices for a given invertible matrix that encodes a change of basis.

i1 : D = makeWeylAlgebra(QQ[x,y]);

i2 : I = ideal(x*dx^2-y*dy^2+2*dx-2*dy, x*dx+y*dy+1);

o2 : Ideal of D

i3 : A = pfaffianSystem I;

i4 : M = matrix {{x,0}, {0,y}};

             2      2
o4 : Matrix D  <-- D

i5 : gaugeTransform(M, A, D)

o5 = {| 0 -1 |, | 0 x/y  |}
      | 0 0  |  | 0 -1/y |

o5 : List

It is also possible to compute the gauge transform of a system of connection matrices containing parameters.

i6 : D = makeWeylAlgebra(frac(QQ[a])[x]);

i7 : I = ideal(x^2*dx^2 + x*dx + (x^2-a^2))

            2  2           2    2
o7 = ideal(x dx  + x*dx + x  - a )

o7 : Ideal of D

i8 : A = pfaffianSystem I

o8 = {| 0           1    |}
      | (-x2+a2)/x2 -1/x |

o8 : List

i9 : M = gaugeMatrix(I,{dx,x^2*dx^2+x*dx+x^2});

                            2                     2
o9 : Matrix (frac(QQ[x, a]))  <-- (frac(QQ[x, a]))

i10 : gaugeTransform(M,A)

o10 = {| -1/x (-x2+a2)/x2a2 |}
       | a2   0             |

o10 : List

See Cosmological correlator for the 2-site chain for an example.

Ways to use gaugeTransform:

gaugeTransform(Matrix,List)
gaugeTransform(Matrix,List,PolynomialRing)

For the programmer

The object gaugeTransform is a method function.

The source of this document is in /build/reproducible-path/macaulay2-1.26.06+ds/M2/Macaulay2/packages/ConnectionMatrices/docs.m2:270:0.

gaugeTransform -- computes the gauge transform of a system of connection matrices

Description

See also

Ways to use gaugeTransform:

For the programmer