module quotients, saturation, and annihilator

Module Quotients

There are two notions associated to the colon construction for modules.

Similar to the case of ideals, the quotient of two $R$-modules $M, N$ contained in the same ambient module is an ideal $M:N$ of elements $f\in R$ such that $f N \subset M$. This is equivalent to the annihilator of the quotient module $(M+N)/M$.

i1 : R = QQ[x,y,z];

i2 : M = image matrix{{x^2,x*y,0},{0,0,z}}

o2 = image | x2 xy 0 |
           | 0  0  z |

                             2
o2 : R-module, submodule of R

i3 : N = image matrix{{x,0},{0,z}}

o3 = image | x 0 |
           | 0 z |

                             2
o3 : R-module, submodule of R

i4 : M:N

o4 = ideal (y, x)

o4 : Ideal of R

The quotient of an $R$-module $M\subset F$ with respect to an ideal $J\subset R$ is the module $M:_F J$ of elements $f\in F$ such that $J f\subset M$. The ambient module $F$ is the ambient module of M.

i5 : M : ideal x

o5 = image | y x 0 |
           | 0 0 z |

                             2
o5 : R-module, submodule of R

Saturation of Modules

The saturation of an $R$-module $M\subset F$ with respect to an ideal $J\subset R$ is an $R$-module $M:_F J^\infty$ of elements $f\in F$ such that $J^N f\subset M$ for some $N$ large enough. If the ideal $J$ is not given, the ideal generated by the variables of the ring $R$ is used.

If $M=M:_F J^\infty$ (or, equivalently, $M=M:_F J$), we say that $M$ is saturated with respect to $J$. We can use this command to remove graded submodules of finite length.

i6 : R = ZZ/32003[a..d];

i7 : m = ideal vars R

o7 = ideal (a, b, c, d)

o7 : Ideal of R

i8 : M = R^1 / (a * m^2)

o8 = cokernel | a3 a2b a2c a2d ab2 abc abd ac2 acd ad2 |

                            1
o8 : R-module, quotient of R

i9 : M / saturate 0_M

o9 = cokernel | a a3 a2b a2c a2d ab2 abc abd ac2 acd ad2 |

                            1
o9 : R-module, quotient of R

Module Annihilators

The annihilator of an $R$-module $M$ is the ideal $\mathrm{ann}(M) = \{ f \in R | f M = 0 \}$.

i10 : R = QQ[a..i];

i11 : M = cokernel genericMatrix(R,a,3,3)

o11 = cokernel | a d g |
               | b e h |
               | c f i |

                             3
o11 : R-module, quotient of R

i12 : annihilator M

o12 = ideal(c*e*g - b*f*g - c*d*h + a*f*h + b*d*i - a*e*i)

o12 : Ideal of R

You may also use the abbreviation ann:

i13 : ann (M/(a*M))

o13 = ideal (a, c*e*g - b*f*g - c*d*h + b*d*i)

o13 : Ideal of R

The source of this document is in /build/reproducible-path/macaulay2-1.26.06+ds/M2/Macaulay2/packages/Saturation/doc.m2:102:0.