betti -- compute the Betti numbers of a toric space

Usage:

betti(k,X)

betti(X)
Inputs:
- k, an integer, (optional)
- X, a small cover,
- X, a quasitoric manifold,
- X, a moment-angle complex,
- X, a normal toric variety,
Optional inputs:
- Minimize (missing documentation) => ..., default value false,
- Weights => ..., default value null,
Outputs:
- an integer, the k-th Betti number of the moment angle complex (if k is provided)
- a list, of all Betti numbers

Description

This method computes the Betti numbers of a toric space (a space with a torus action, ie, small cover, quasitoric manifold, moment-angle complex and normal toric variety). For small-covers, the formula of Suciu-Trevisan (https://arxiv.org/abs/1302.2342) is used. For quasitoric manifolds, the classical formula of Davis-Januszkiewicz (http://dx.doi.org/10.1215/S0012-7094-91-06217-4) is used. For moment-angle complexes, the theorem of Baskakov-Buchstaber-Panov (https://arxiv.org/abs/math/0407189) is used. For normal toric varieties, the result of Franz (https://arxiv.org/abs/math/0308253) is used. If a dimension k is specified, then only the k-th Betti number of X is computed. If no dimension is specified, all the Betti numbers between 0 and 2m are computed (where m is either the dimension of the small-cover, quasitoric manifold or normal toric variety X, or it is the number of vertices in the underlying simplicial complex of the moment-angle complex).

The small cover over a square with the characteristic matrix $\begin{pmatrix}1 & 1 & 0 & 1 \\ 0 & 1 & 1 & 1\end{pmatrix}$ is the Klein bottle, as indicated by its betti numbers.

i1 : needsPackage "SimplicialComplexes"

o1 = SimplicialComplexes

o1 : Package

i2 : R = QQ[a..d]

o2 = R

o2 : PolynomialRing

i3 : K = simplicialComplex {a*b, b*c, c*d, d*a}

o3 = simplicialComplex | cd ad bc ab |

o3 : SimplicialComplex

i4 : lambda = matrix{{1, 1, 0, 1}, {0, 1, 1, 1}}

o4 = | 1 1 0 1 |
     | 0 1 1 1 |

              2       4
o4 : Matrix ZZ  <-- ZZ

i5 : X = smallCover(K, lambda)

o5 = SmallCover{QTMCharacteristicMatrix => | 1 1 0 1 |                   }
                                           | 0 1 1 1 |
                QTMDimension => 2
                QTMSimplicialComplex => simplicialComplex | cd ad bc ab |

o5 : SmallCover

i6 : betti X

o6 = {1, 1, 0}

o6 : List

The quasitoric manifold over a triangle with the characteristic matrix $\begin{pmatrix}1 & 0 & -1 \\ 0 & 1 & -1\end{pmatrix}$ is the complex projective plane $\mathbb{CP}^2$, as indicated by its betti numbers.

i7 : needsPackage "SimplicialComplexes"

o7 = SimplicialComplexes

o7 : Package

i8 : R = QQ[a..c]

o8 = R

o8 : PolynomialRing

i9 : K = simplicialComplex {a*b, b*c, c*a}

o9 = simplicialComplex | bc ac ab |

o9 : SimplicialComplex

i10 : lambda = matrix{{1, 0, -1}, {0, 1, -1}}

o10 = | 1 0 -1 |
      | 0 1 -1 |

               2       3
o10 : Matrix ZZ  <-- ZZ

i11 : X = quasiToricManifold(K, lambda)

o11 = QuasiToricManifold{QTMCharacteristicMatrix => | 1 0 -1 |                 }
                                                    | 0 1 -1 |
                         QTMDimension => 4
                         QTMSimplicialComplex => simplicialComplex | bc ac ab |

o11 : QuasiToricManifold

i12 : betti X

o12 = {1, 0, 1, 0, 1}

o12 : List

The moment-angle complex corresponding to the simplicial complex consisting of two disjoint vertices is homeomorphic to $S^3$, the 3-sphere as indicated by its Betti numbers.

i13 : needsPackage "SimplicialComplexes"

o13 = SimplicialComplexes

o13 : Package

i14 : R = QQ[x,y]

o14 = R

o14 : PolynomialRing

i15 : K = simplicialComplex {x, y}

o15 = simplicialComplex | y x |

o15 : SimplicialComplex

i16 : Z = momentAngleComplex K

o16 = MomentAngleComplex{MACSimplicialComplex => simplicialComplex | y x |}

o16 : MomentAngleComplex

i17 : betti Z

o17 = {1, 0, 0, 1, 0}

o17 : List

Let $\mathcal{Z}_K$ be the moment-angle corresponding to the simplicial complex consisting on 3 vertices, with an edge and a disjoint vertex. By Hochster's formula, its third cohomology $H^3(\mathcal{Z}_K)$ will have rank $2$. We can verify this as follows,

i18 : needsPackage "SimplicialComplexes"

o18 = SimplicialComplexes

o18 : Package

i19 : R = QQ[x..z]

o19 = R

o19 : PolynomialRing

i20 : K = simplicialComplex {x, y*z}

o20 = simplicialComplex | x yz |

o20 : SimplicialComplex

i21 : Z = momentAngleComplex K

o21 = MomentAngleComplex{MACSimplicialComplex => simplicialComplex | x yz |}

o21 : MomentAngleComplex

i22 : betti (3, Z)

o22 = 2

The moment-angle corresponding to the boundary $\partial \Delta^2$ of the 2-simplex is homeomorphic to $S^5$, as reflected by its Betti numbers.

i23 : needsPackage "SimplicialComplexes"

o23 = SimplicialComplexes

o23 : Package

i24 : R = QQ[x..z]

o24 = R

o24 : PolynomialRing

i25 : K = simplicialComplex {x*y, y*z, x*z}

o25 = simplicialComplex | yz xz xy |

o25 : SimplicialComplex

i26 : Z = momentAngleComplex K

o26 = MomentAngleComplex{MACSimplicialComplex => simplicialComplex | yz xz xy |}

o26 : MomentAngleComplex

i27 : betti Z

o27 = {1, 0, 0, 0, 0, 1, 0}

o27 : List

The consider the normal toric variety $\mathbb{CP}^1 \times \mathbb{CP}^1$ with two fixed points $([1:0], [1:0])$ and $([0:1], [0:1])$ removed. Its betti numbers can be computed as follows:

i28 : needsPackage "NormalToricVarieties"

o28 = NormalToricVarieties

o28 : Package

i29 : rayList = {{1, 0}, {0, 1}, {-1, 0}, {0, -1}}

o29 = {{1, 0}, {0, 1}, {-1, 0}, {0, -1}}

o29 : List

i30 : coneList = {{1, 2}, {0, 3}}

o30 = {{1, 2}, {0, 3}}

o30 : List

i31 : X = normalToricVariety (rayList, coneList)

o31 = X

o31 : NormalToricVariety

i32 : betti X
warning: clearing value of symbol c to allow access to subscripted variables based on it
       : debug with expression   debug 8545   or with command line option   --debug 8545

o32 = {1, 0, 2, 1, 0}

o32 : List

Ways to use betti:

betti(GroebnerBasis) -- see betti -- display or modify a Betti diagram
betti(Ideal) -- see betti -- display or modify a Betti diagram
betti(Matrix) -- see betti -- display or modify a Betti diagram
betti(Module) -- see betti -- display or modify a Betti diagram
betti(MomentAngleComplex)
betti(NormalToricVariety)
betti(QuasiToricManifold)
betti(SmallCover)
betti(ZZ,MomentAngleComplex)
betti(ZZ,NormalToricVariety)
betti(ZZ,QuasiToricManifold)
betti(ZZ,SmallCover)
betti(BettiTally) -- view and set the weight vector of a Betti diagram
betti(CoherentSheaf) (missing documentation)
betti(Complex) -- display of degrees in a complex

For the programmer

The object betti is a method function with options.

The source of this document is in /build/reproducible-path/macaulay2-1.26.06+ds/M2/Macaulay2/packages/ToricTopology/Documentation.m2:474:0.