regularFineTriangulation -- a regular fine triangulation of a point or vector configuration

Usage:

T = regularFineTriangulation A

T = regularFineTriangulation T0
Inputs:
- A, a matrix, whose columns are the points of the configuration
- T0, an instance of the type Triangulation, a starting triangulation, possibly neither fine nor regular
Optional inputs:
- Homogenize => a Boolean value, default value true, if true (default), $A$ is augmented with a final row of $1$'s and treated as a point set; if false, the columns are treated as a vector configuration in their own right; ignored when the input is a Triangulation
Outputs:
- T, an instance of the type Triangulation, a regular fine triangulation, or null if no such triangulation exists (Matrix form, when Homogenize => false)

Description

With a Matrix input, constructs a regular fine triangulation by calling topcomRegularFineTriangulation and wrapping the result in a Triangulation. When Homogenize => false and $A$ is non-acyclic, topcom is unreliable; in that case the result is built via regularFineFanTriangulation (and, if it is not already fine, refined via makeFine).

i1 : A = transpose matrix {{0,3},{0,1},{-1,-1},{1,-1},{-4,-2},{4,-2}}

o1 = | 0 0 -1 1  -4 4  |
     | 3 1 -1 -1 -2 -2 |

              2       6
o1 : Matrix ZZ  <-- ZZ

i2 : T = regularFineTriangulation A

o2 = triangulation {{0, 1, 2}, {0, 1, 3}, {0, 2, 4}, {0, 3, 5}, {1, 2, 3}, {2, 3, 4}, {3, 4, 5}}

o2 : Triangulation

i3 : isFine T

o3 = true

i4 : isRegularTriangulation T

o4 = true

Given a Triangulation $T_0$ that is not (yet) fine or regular, this walks the bistellar flip graph: first via support-increasing flips (makeFine) to reach a fine triangulation, then via fine flips until a regular one is encountered. Errors if the second stage exhausts the fine-flip-connected component without finding a regular triangulation.

i5 : A = transpose matrix {{-1,-1,1,1},{-1,-1,1,2},{-1,-1,2,1},{-1,3,-1,-1},{2,-1,-1,-1},{-1,1,0,0}}

o5 = | -1 -1 -1 -1 2  -1 |
     | -1 -1 -1 3  -1 1  |
     | 1  1  2  -1 -1 0  |
     | 1  2  1  -1 -1 0  |

              4       6
o5 : Matrix ZZ  <-- ZZ

i6 : t0 = triangulation(A, {{0,1,2,3},{0,1,2,4},{0,1,3,4},{0,2,3,4},{1,2,3,4}})

o6 = triangulation {{0, 1, 2, 3}, {0, 1, 2, 4}, {0, 1, 3, 4}, {0, 2, 3, 4}, {1, 2, 3, 4}}

o6 : Triangulation

i7 : isFine t0

o7 = false

i8 : T = regularFineTriangulation t0

o8 = triangulation {{0, 1, 2, 4}, {0, 1, 2, 5}, {0, 1, 4, 5}, {0, 2, 4, 5}, {1, 2, 3, 4}, {1, 2, 3, 5}, {1, 3, 4, 5}, {2, 3, 4, 5}}

o8 : Triangulation

i9 : isFine T

o9 = true

i10 : isRegularTriangulation T

o10 = true

Caveat

On the Matrix form with Homogenize => false, the function returns null when makeFine fails to reach a fine triangulation by support-increasing flips (for instance when $A$ has a zero column, which cannot be a ray of any maximal cone).

Ways to use regularFineTriangulation:

regularFineTriangulation(Matrix)
regularFineTriangulation(Triangulation)

For the programmer

The object regularFineTriangulation is a method function with options.

The source of this document is in /build/reproducible-path/macaulay2-1.26.06+ds/M2/Macaulay2/packages/Triangulations.m2:1343:0.

regularFineTriangulation -- a regular fine triangulation of a point or vector configuration

Description

Caveat

See also

Ways to use regularFineTriangulation:

For the programmer